Čtení schránky - metafile   zodpovězená otázka

VB.NET

před 16 lety

Petr Žižka
 

Hodnocení 21     Příspěvků 116

Zdravím,

Zkouším číst obsah schránky a nemůžu přijít kde dělám chybu. Ve schránce je kus textu z Wordu a potřebuji jej jako Obrázek - Metafile. Do PPT lze bez problému jako metafile zkopírovat.

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim myObject As DataObject
Dim Formats() As String
 
 
myObject = Clipboard.GetDataObject
Formats = myObject.GetFormats
 
If Not Formats.Contains("MetaFilePict") Then Exit Sub
 
Dim myMeta As Drawing.Image
Dim myStream As IO.MemoryStream
 
myStream = myObject.GetData("MetaFilePict", True)
myMeta = New Imaging.Metafile(myStream)

Na posledním příkazu to hází chybu - Generic error in GDI+.

Nemohu bohužel použít myObject.getimage, protože se to tváří, že tam obrázek není a proto to zkouším přes memorystream.

Máte s tím někdo nějaké zkušenosti prosím?

Moc dík. P.
nahlásit spamnahlásit spam 0 odpovědětodpovědět

před 16 lety

Ondřej Linhart
 

Hodnocení -553     Příspěvků 3274

Formát grafiky, který ukládá Microsoft Word do schránky prostě není kompatibilní s grafickými objekty z .NET Frameworku. Jestli je možné použít to co je ve schránce v kombinaci s grafickými objekty z Frameworku zjistíte pomocí metody DataObject.ContainsImage.
nahlásit spamnahlásit spam 0 odpovědětodpovědět

před 16 lety

Petr Žižka
 

Hodnocení 21     Příspěvků 116

Moc děkuji - bohužel jste mi potrvdil toho čeho jsem se obával.

DataObject.ContainsImage je false a právě proto GetImage také nemá smysl používat.

(když použiju např. Inkscape, tak vše funguje jak má a je to plně kompatibilní s IMAGE objektem.)

Takže to chce vyšpionit jak na formát používaný wordem:(
nahlásit spamnahlásit spam 0 odpovědětodpovědět

před 16 lety

Petr Žižka
 

Hodnocení 21     Příspěvků 116

Třeba bude někoho zajímat řešení, které jsem našel na netu. nejsem autor, jen jsem to upravil aby to bylo funkcni. Z diskuzí jsem pochopil, že s kompatabilitou metafilu WIN vs .NET clipboard je problém a tak se musí použít win API pro jeho čtení.

Takže stačí zavolat následující funkci, která vrátí objekt typu metafile nebo nic, pokud schránka neobsahuje metafile.

?
1
If Clipboard.GetDataObject.GetFormats.Contains("MetaFilePict") Then Mymetafile = MetafileClipboard.GetMetafile()

Tady je kompletní kód:

?
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
Imports System.Runtime.InteropServices
 
Class MetafileClipboard
    Shared Function GetMetafile() As Imaging.Metafile
        Const CF_ENHMETAFILE As Integer = 14
 
        Dim ip As IntPtr
        Dim metaFile As System.Drawing.Imaging.Metafile
        Dim bRet As Boolean
 
        bRet = ClipboardAPI.OpenClipboard(My.Application.OpenForms(0).Handle)
        If bRet = True Then
            'Verify the clipboard contains data available
            'as an enhanced metafile.
            bRet = ClipboardAPI.IsClipboardFormatAvailable(CF_ENHMETAFILE) <> 0
        End If
 
        If bRet = True Then
            'Store the clipboard's contents in the IntPtr.
            ip = ClipboardAPI.GetClipboardData(CF_ENHMETAFILE)
        End If
 
        'Verify the IntPrt contains data before proceeding. Passing
        'an empty IntPtr to System.Drawing.Imaging.Metafile results
        'in an exception.
        If Not IntPtr.Zero.Equals(ip) Then
            metaFile = New System.Drawing.Imaging.Metafile(ip, True)
            ClipboardAPI.CloseClipboard()
             
            Return metaFile
        Else
            Return Nothing
        End If
    End Function
End Class
 
Class ClipboardAPI
    <DllImport("user32.dll", EntryPoint:="OpenClipboard", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
    Public Shared Function OpenClipboard(ByVal hWnd As IntPtr) As Boolean
    End Function
 
    <DllImport("user32.dll", EntryPoint:="EmptyClipboard", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
    Public Shared Function EmptyClipboard() As Boolean
    End Function
 
    <DllImport("user32.dll", EntryPoint:="SetClipboardData", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
     Public Shared Function SetClipboardData(ByVal uFormat As Integer, ByVal ByValhWnd As IntPtr) As IntPtr()
    End Function
 
    <DllImport("user32.dll", EntryPoint:="CloseClipboard", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
    Public Shared Function CloseClipboard() As Boolean
    End Function
 
    <DllImport("user32.dll", EntryPoint:="GetClipboardData", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
    Public Shared Function GetClipboardData(ByVal uFormat As Integer) As IntPtr
    End Function
 
    <DllImport("user32.dll", EntryPoint:="IsClipboardFormatAvailable", SetLastError:=True, ExactSpelling:=True, CallingConvention:=CallingConvention.StdCall)> _
    Public Shared Function IsClipboardFormatAvailable(ByVal uFormat As Integer) As Short
    End Function
End Class
nahlásit spamnahlásit spam 3 / 3 odpovědětodpovědět

přihlásit pomocí externího účtu

přihlásit pomocí jména a hesla

Uživatel:
Heslo:

zapomenuté heslo

 

založit nový uživatelský účet

zaregistrujte se

 
zavřít

Nahlásit spam

Opravdu chcete tento příspěvek nahlásit pro porušování pravidel fóra?

Nahlásit Zrušit

Chyba

zavřít

feedback