dotNETportal.cz

Máte pravdu bez reference události nejdou, resp. nejdou události, kde jsou v parametru nějaké typy z Excel knihovny.

Následující kód použije Reflection pro získání delegáta a zaregistrování události, ale chodí to pouze pokud v parametrech události nejsou typy z chybějící reference Excelu:

Option Strict Off

Private Sub ExcelTest()
        Dim ExcelType As Type = Type.GetTypeFromProgID("Excel.Application")
        Dim Excel As Object = Activator.CreateInstance(ExcelType)

        Excel.Visible = True

        Dim ExcelAssembly As Assembly = ExcelType.Assembly
        Dim AppEventsType As Type = ExcelAssembly.GetType("Microsoft.Office.Interop.Excel.AppEvents_Event")

        Dim AfterCalculateDelegateType As Type = ExcelAssembly.GetType("Microsoft.Office.Interop.Excel.AppEvents_AfterCalculateEventHandler")
        Dim AfterCalculateDelegate As [Delegate] = [Delegate].CreateDelegate(AfterCalculateDelegateType, Me, "Application_AfterCalculate")
        AppEventsType.GetEvent("AfterCalculate").AddEventHandler(Excel, AfterCalculateDelegate)

        'Chyba: 'Cannot bind to the target method because its signature or security transparency is not compatible with that of the delegate type.'
        'Dim AppEventsNewWorkbookDelegateType As Type = ExcelAssembly.GetType("Microsoft.Office.Interop.Excel.AppEvents_NewWorkbookEventHandler")
        'Dim AppEventsNewWorkbookDelegate As [Delegate] = [Delegate].CreateDelegate(AppEventsNewWorkbookDelegateType, Me, "Application_NewWorkbook")
        'AppEventsType.GetEvent("NewWorkbook").AddEventHandler(Excel, AppEventsNewWorkbookDelegate)
    End Sub

    Private Sub Application_AfterCalculate()
        MessageBox.Show("AfterCalculate")
    End Sub

    Private Sub Application_NewWorkbook(Workbook As Object) 'Měl by být Microsoft.Office.Interop.Excel.Workbook
        MessageBox.Show("NewWorkbook")
    End Sub

Asi Vám to moc nepomůže, ale co kdyby.

Odlišnosti musím poladit, aby pracovalo dle příslušné verze, jinak skvělé.

Např. AfterCalculate ve verzi 2007, ale ve verzi 2003 SheetCalculate...

Např. událost NewWokbook je stejná a pro obě verze lze použít:

Dim AppEventsNewWorkbookDelegateType As Type = ExcelAssembly.GetType("Microsoft.Office.Interop.Excel.AppEvents_NewWorkbookEventHandler")
        Dim mi As MethodInfo = Me.GetType().GetMethod("Application_NewWorkbook", BindingFlags.NonPublic Or BindingFlags.Instance)
        Dim AppEventsNewWorkbookDelegate As [Delegate] = [Delegate].CreateDelegate(AppEventsNewWorkbookDelegateType, Me, mi)
        AppEventsType.GetEvent("NewWorkbook").AddEventHandler(Excel, AppEventsNewWorkbookDelegate)

Workbook as Object v deklaraci metody to překousne.

Asi Vám to moc nepomůže, ale co kdyby.

Naopak, velmi jste mi pomohl a moc Vám děkuji za Vaši odpověď.