dotNETportal.cz

Pokud by Vám stačila nápověda jen při psaní programu, pak je řešení jednoduché. Použijete XML dokumentaci:

        Public Enum SortBy As Integer
            ''' <summary>
            ''' Náhodné řazeí
            ''' </summary>
            ''' <remarks></remarks>
            Random = 0
            ''' <summary>
            ''' Dle jména vzestupně
            ''' </summary>
            ''' <remarks></remarks>
            Name_Asc = 1                 ' řazeno dle jména vzestupně
            ''' <summary>
            ''' Dle jména sestupně
            ''' </summary>
            ''' <remarks></remarks>
            Name_Des = 2                 ' řazeno dle jména sestupně
        End Enum

Ale to asi není to co potřebuje. Váš problém bych řešil atributama. Kód snad mluví sám za sebe. Nejdřív je definice atributu třídou DescriptionAttribute, pak definice Enumu s aplikovanými atributy a nakonec kód, který přečte atribut:

    <AttributeUsage(AttributeTargets.Field)> _
    Public Class DescriptionAttribute
        Inherits Attribute

        Private desc As String
        Sub New(ByVal desc As String)
            Me.desc = desc
        End Sub

        ReadOnly Property Description()
            Get
                Return desc
            End Get
        End Property
    End Class

    Public Enum SortBy As Integer
        <DescriptionAttribute("Náhodné řazení")> Random = 0
        <DescriptionAttribute("Dle jména vzestupně")> Name_Asc = 1
        <DescriptionAttribute("Dle jména sestupně")> Name_Desc = 2
    End Enum

    Public Function GetDescriptionForField(ByVal tp As Type, ByVal fldName As String) As String
        Dim DescAtr As DescriptionAttribute = _
        CType(Attribute.GetCustomAttribute(tp.GetField(fldName), GetType(DescriptionAttribute)), DescriptionAttribute)
        If DescAtr Is Nothing Then Return String.Empty
        Return DescAtr.Description
    End Function

    Public Sub main()
        For Each fld As String In [Enum].GetNames(GetType(SortBy))
            Console.WriteLine(String.Format("{0} - atribut popisu: {1}", _
                fld, GetDescriptionForField(GetType(SortBy), fld)))
        Next
        Console.ReadKey()
    End Sub

Jde už o něco složitější implementaci. Proto pokud není něco jasného, klidně se ptejte.

Snad to pomůže.

Pokud chcete velice jednoduše používat DataBinding (naplnit ComboBox požadovanými popisnými hodnotami pouze jediným řádkem: ComboBox1.DataSource = [Enum].GetValues(GetType(SortBy))), doporučuji nastudovat tento článek: http://www.codeproject.com/KB/cs/Localiz...

Jedná se o implementaci vlastního EnumConverter. Výše uvedený příklad nelze použít pro DataBinding.